An educational program for everyone (Rainbow 1981-08)

WELCOME
Looking for CoCo help? If you are trying to do something with your old Color Computer, read this quick reference. Want to contribute to this wiki? Be sure to read this first. This CoCo wiki project was started on October 29, 2004. --OS-9 Al

See Recent Changes. | About this site. | Join the E-Mail List or Facebook Group. | Contact me with updates/questions.

This page was last updated on 11/4/2020. Total Pages: 744. Total Files: 994.

---

Home / Publications / Rainbow / Rainbow 1981 / Rainbow 1981-08 - An educational program for everyone (Rainbow 1981-08)

---

Here is a program that can really be of use to just about everyone in the family. It is called AMORT and it deals with money at interest.

On one level, it can be used as a regular interest program that wiII help you figure out such things as how much it will cost you a month to buy the new disc drives for your COLOR computer. That's not a bad thing to know.

On the other level, however, there are some explanations built in to help teach those in familiar with the terms involved with money at interest just what the terms mean. And there is a "cute" little default if you don't make the proper response to the amount of time the loan has to run question.

AMORT is written for non-Extended Color Basic, which -- as you know -- does not have the ability to raise numbers to powers. There is a way around that limitation of course, and it can be found in lines 30 and 60. For those of you who do have Extended Color Basic. you might wish to change those lines. The result will be a slightly more accurate result -- especially on the more complicated calculations for longer periods of time.

However, non-Extended Color users will have to change the PRINTUSING com¬mands in lines 140-146, 310 and 340. Just take out the reference to USING and the pound- and dollar-signs. That way, the program will run without any modification on your part.

Finally, notice the use of the variable PO to send output to the printer. If you want. you can eliminate the references to PO, but you would probably be better off leaving them in - in anticipation of the time when you might get a printer. Just answer "No" to the question in line 32 and no harm is done.

Here is the listing:

3 '*********************
4 '*   AMORT PROGRAM   *
5 '* (c) FALSOFT, 1981 *
6 '*********************
11 C=0:CLS
12 PRINT "   THIS PROGRAM WILL GENERATE    AN AMORITZATION SCHEDULE FOR   MOST COMMON LOANS."
13 PRINT:PRINT ">PLEASE FOLLOW DIRECTIONS BELOW<"
14 PRINT STRING$(32,"=")
15 INPUT "FIRST, WE NEED TO KNOW HOW MUCH    YOU WANT TO BORROW. THIS IS    CAL LED THE PRINCIPAL.  WHAT   IS THE PRINCIPAL";P
16 CLS:PRINT:PRINT
17 PA=P
20 INPUT "NOW, WE MUST KNOW THE NUMBER OF    PERIODS. THE LOAN WILL RUN.      IF YOU WISH TO ENTER THE       PERIODS BY MONTH.. TYPE IN      THE WORD 'MONTH.' IF ITS       YEARS, TYPE IN 'YEAR.' WHICH    IS IT";A$
21 IF LEFT$(A$,1)="M" THEN 270
22 IF LEFT$(A$,1)="Y" THEN 260
23 GOTO250
30 CLS:PRINT:PRINT
31 INPUT "LASTLY, WE NEED TO KNOW WHAT       INTEREST RATE YOU WILL BE      CHA RGED ON THE LOAN.  WHAT      IS THE RATE";R
32 INPUT "  DO YOU WANT A PRINTOUT";PO$: IF LEFT$(PO$,1)="Y" THEN PO=1
35 CLS
40 I=R/12:I=I/100
50 T=1:FOR X=1 TO L
60 T=T*(1+I):NEXT X:T=1/T
70 T=1-T
80 M=P*I/T
90 GOSUB200
100 FOR Z=1 TO L
120 R=(INT(P*I*100+.5))/100
130 B=M-A:P=P-B
140 PRINTTAB(0);:PRINTUSING"###";Z;:IF PO THEN PRINT#-2,TAB(0);:PRINT#-2, USING"###";Z;
142 PRINTTAB(3);:PRINTUSING"###,###.##";P;:IF PO THEN PRINT#-2,TAB(3);:PRINT#-2,USING"###,###.##";P;
144 PRINTTAB(14);:PRINTUSING"#,###.##";B;:IF PO THEN PRINT#-2,TAB(14);:PRINT#-2,USING"#,###.##";B;
146 PRINTTAB(23);:PRINTUSING"#,###.##";A:IF PO THEN PRINT#-2,TAB(23);:PRINT#-2,USING"#,###.##";A
160 Q=Q+1:C=C+1:AT=AT+A:NEXT Z
165 GOTO300
170 END
200 CLS:MA=M+.005:MA= INT(MA*100)/100:IF PO THEN PRINT#-2,TAB(4)"AMORITIZATION SCHEDULE"
201 IF PO THEN PRINT#-2,"PAYMENTS ARE $";MA
202 IF PO THEN PRINT#-2,TAB(4) "BALANCE";
204 IF PO THEN PRINT#-2,TAB(14) "PMT/PRIN";
206 IF PO THEN PRINT#-2,TAB(24) "PMT/INT"
208 PRINT "PAYMENT ARE $";MA
210 PRINTTAB(4)"BALANCE"TAB(14)"PMT/PRIN"TAB(24)"PMT/INT"
220 RETURN
250 CLS(5):PRINT@82,"NO!";
252 PRINT@162,"NEIN!";
254 PRINT@249,"NYET!";
255 PRINT@288," NO NO NO NO NO NO NO NO NO NO"
257 PRINT@132,"   ";:PRINT"   YOU DID NOT FOLLOW THE         DIRECTIONS PROPERLY. ENTER               ONLY THE WORD 'YEAR' OR                      THE WORD 'MONTH.' NOW.  TRY    AGAIN."
258 FOR WN=1 TO 3200:NEXT WN:CLS:PRINT:PRINT:GOTO20
260 PRINT
261 INPUT "O.K., NOW WILL YOU PLEASE ENTER    THE NUMBER OF YEARS BEFORE     YOU PAY OFF THE LOAN";YR
265 L=YR*12:GOTO 30
270 PRINT
271 INPUT "ALL RIGHT, NOW WILL YOU PLEASE    ENTER THE NUMBER OF MOHTHS     IT WILL TAKE TO FAY OFF THE    LOAN";L
275 GOTO 30
300 IF PO THEN PRINT#-2, " ":PRINT#-2,TAB(10)"LOAN  SUMMARY":PRINT#-2, TAB(10)"==========="
310 IF PO THEN PRINT#-2,TAB(5)"PRINCIPAL:";PRINT#-2,USING"#####, ###.##";PA
320 IF PO THEN PRINT#-2," PERIODS:"L;:PRINT#-2,"         RATE: ";:PRINT#-2,USING"##.##";R;:PRINT#-2,"%"
330 IF PO THEN PRINT#-2,STRING$(31,"-")
340 IF PO THEN PRINT#-2,"TOTAL INTEREST: ";:PRINT#-2,USING"$$###,###.##";AT
350 IF PO THEN PRINT#-2," ":PRINT#-2," ":PRINT#-2," "

Screen Shots

• 

  Initial Amount

• 

  Month?

• 

  How Many?

• 

  Rate & Print?

• 

  Result

Links

See Rainbow Magazine 1981-08 Pag 8, in archive.org
File:1982-07.dsk Programs in 1981-08 Disk Image